pxtry.f

Go to the documentation of this file.

CDECK  ID>, PXTRY.
******............................................................******
       SUBROUTINE pxtry(COSR,NTRAK,PU,PP,OAXIS,NAXIS,PNEW,NEWLIS,OK)
******............................................................******
*
      IMPLICIT NONE
      INTEGER mxtrak
      parameter(mxtrak=200)
       INTEGER ntrak
       REAL cosr,pu(3,mxtrak),pp(4,mxtrak),oaxis(3)
       LOGICAL ok
       LOGICAL newlis(mxtrak)
       REAL naxis(3),pnew(4)
*** Finds all particles in cone of size COSR about OAXIS direction.
*** Calculates 4-momentum sum of all particles in cone (PNEW) , and
*** returns this as new jet axis NAXIS (Both unit Vectors)
       INTEGER n,mu
       REAL cosval,normsq,norm
*
       ok = .false.
       DO 100 mu=1,4
          pnew(mu)=0.0
100    CONTINUE
       DO 110 n=1,ntrak
          cosval=0.0
          DO 120 mu=1,3
             cosval=cosval+oaxis(mu)*pu(mu,n)
120       CONTINUE
          IF (cosval.GE.cosr)THEN
             newlis(n) = .true.
             ok = .true.
             DO 130 mu=1,4
                pnew(mu) = pnew(mu) + pp(mu,n)
130          CONTINUE
          ELSE
             newlis(n)=.false.
          ENDIF
110   CONTINUE
*** If there are particles in the cone, calc new jet axis
       IF (ok) THEN
          normsq = 0.0
          DO 140 mu = 1,3
            normsq = normsq + pnew(mu)**2
140       CONTINUE
          norm = sqrt(normsq)
          DO 150 mu=1,3
            naxis(mu) = pnew(mu)/norm
150       CONTINUE
       ENDIF
       RETURN
       END