pxord.f

Go to the documentation of this file.

CDECK  ID>, PXORD.
******............................................................******
       SUBROUTINE pxord(EPSLON,NJET,NTRAK,JETLIS,PJ)
******............................................................******
*
*** Routine to put jets into order and eliminate tose less than EPSLON
*.
*. Modification Log.
*. 22-Apr-97: D. Chrisman - Dimension ELIST and INDEX with MXPROT
*.                          instead of 100.
*.
      IMPLICIT NONE
      INTEGER mxtrak,mxprot
      parameter(mxtrak=200,mxprot=100)
      INTEGER i, j, index(mxprot)
      REAL ptemp(4,mxprot), elist(mxprot)
      INTEGER njet,ntrak
      LOGICAL jetlis(mxprot,mxtrak)
      LOGICAL logtmp(mxprot,mxtrak)
      REAL epslon,pj(4,mxprot)
*** Puts jets in order of energy: 1 = highest energy etc.
*** Then Eliminate jets with energy below EPSLON
*
*** Copy input arrays.
      DO 100 i=1,njet
         DO 110 j=1,4
            ptemp(j,i)=pj(j,i)
110      CONTINUE
         DO 120 j=1,ntrak
            logtmp(i,j)=jetlis(i,j)
120      CONTINUE
100   CONTINUE
      DO 150 i=1,njet
         elist(i)=pj(4,i)
150   CONTINUE
*** Sort the energies...
      CALL pxsorv(njet,elist,index,'I')
*** Fill PJ and JETLIS according to sort ( sort is in ascending order!!)
      DO 200 i=1, njet
         DO 210 j=1,4
            pj(j,i)=ptemp(j,index(njet+1-i))
210      CONTINUE
         DO 220 j=1,ntrak
            jetlis(i,j)=logtmp(index(njet+1-i),j)
220      CONTINUE
200   CONTINUE
** Jets are now in order
*** Now eliminate jets with less than Epsilon energy
      DO 300, i=1, njet
         IF (pj(4,i) .LT. epslon) THEN
            njet=njet-1
            pj(4,i)=0.
         ENDIF
300   CONTINUE
      RETURN
      END