pxlcl5.f

Go to the documentation of this file.

CDECK  ID>, PXLCL5.
      SUBROUTINE pxlcl5 (NTRAK,ITKDM,PTRAK,IMODE,XMIN,MNJET,
     +                   mxjet,njet,pjet,ipass,ijmul,ierr)
*.*********************************************************
*. ------
*. PXLCL5
*. ------
*. Jet-finding routine using the Jetset algorithm.
*. The implementation here is without a common block, however.
*. Thus this routine may be used regardless of whether the
*. Jetset6.3 or Jetset7.1 library might be linked.  It is
*. not necessary to link to Jetset, however.
*. Usage     :
*.
*.      INTEGER  ITKDM,MXTRK
*.      PARAMETER  (ITKDM=5.or.more,MXTRK=1.or.more)
*.      INTEGER  MXJET
*.      PARAMETER  (MXJET=10)
*.      INTEGER  IPASS (MXTRK),IJMUL (MXJET)
*.      INTEGER  NTRAK,NJET,IERR,IMODE,MNJET
*.      REAL  PTRAK (ITKDM,MXTRK),PJET (5,MXJET)
*.      REAL  XMIN
*.
*.      NTRAK = 1.to.MXTRAK
*.      IMODE = 1.to.4 (Jetset7.1 default = 1)
*.      XMIN  = 2.5    (Jetset7.1 default = 2.5 for IMODE = 1,2,3;
*.                                       = 0.05 for IMODE = 4)
*.      MNJET = 1.to.MXJET  (= 1 for most purposes)
*.      CALL PXLCL5 (NTRAK,ITKDM,PTRAK,IMODE,XMIN,MNJET,
*.     +             MXJET,NJET,PJET,IPASS,IJMUL,IERR)
*.
*. INPUT     : NTRAK     Total number of particles
*. INPUT     : ITKDM     First dimension of PTRAK array
*. INPUT     : PTRAK     Particle momentum array: Px,Py,Pz,E,M
*. INPUT     : IMODE     Jetfinder mode (= MSTU(46) in Jetset7.1)
*. INPUT     : XMIN      Jet resolution parameter
*.                           equivalent to PARU(44) for IMODE = 1,2,3
*.                           equivalent to PARU(45) for IMODE = 4
*. INPUT     : MNJET     The minimum number of jets to reconstruct
*. INPUT     : MXJET     The maximum number of jets permitted
*. OUTPUT    : NJET      Number of jets found
*. OUTPUT    : PJET      5-momenta of reconstructed jets
*. OUTPUT    : IPASS(k)  Particle k belongs to jet number IPASS(k)
*. OUTPUT    : IJMUL(i)  Jet i contains IJMUL(i) particles
*. OUTPUT    : IERR      = 0 if all is OK ;   = -1 otherwise
*.
*. CALLS     : PXLUC5,PXMAS4,PXPRNT,PXPRIV
*. CALLED    : By User
*.
*. AUTHOR    :  J.W.Gary
*. CREATED   :  19-Jun-88
*. LAST MOD  :  15-Feb-89
*.
*. Modification Log.
*. 15-Feb-89  Integrate with PXLUC5  J.W.Gary
*. 12-May-97 D. Chrisman, remove declaration of unused variables
*.             DMIN, MINTR and TGEN.
*.
*.*********************************************************
      IMPLICIT NONE
      INTEGER  iolun,nrludm
      parameter(iolun=6,nrludm=2000)
      INTEGER  ntrak,mxjet,ix1,ix2,itkdm,njet,ierr,nlund,
     +         mstu46,mstu47,imode,mnjet
      INTEGER  ipass (*),ijmul (*)
      REAL  ptrak (itkdm,*),plund (nrludm,5),pjet (5,*)
      REAL  xmin,paru44,paru45
      LOGICAL  lprt
      DATA  lprt / .false. /

      ierr = 0
*  select jetfinder mode
*  ------ --------- ----
      mstu46 = imode
      mstu47 = mnjet
      IF (mstu46.LT.1.OR.mstu46.GT.4) THEN
          WRITE (6,fmt='(''PXLCL5: Error, MSTU46 ='',I12)') mstu46
          go to 995
      END IF
      paru44 = xmin
      paru45 = xmin
      IF (ntrak.LE.1) THEN
          WRITE (iolun,fmt='('' PXLCL5: Error, NTRAK ='',I4)')
     +           ntrak
          go to 995
      END IF
*  Pack Jetset arrays
*  ---- ------ ------
      nlund = ntrak
      DO 110  ix1 = 1,ntrak
          DO 100  ix2 = 1,5
              plund(ix1,ix2) = ptrak(ix2,ix1)
 100      CONTINUE
 110  CONTINUE
*  Call Jetset routine for cluster-finding
*  ---- ------ ------- --- ------- -------
      CALL pxluc5(nlund,nrludm,plund,mstu46,mstu47,
     +             paru44,paru45,njet,ijmul,ipass)
      IF (njet.LT.1) THEN
          WRITE (iolun,fmt='('' PXLCL5: ERROR, NJET='',
     +           I6)') njet
          ierr = -1
          RETURN
      ELSE IF (njet.GT.mxjet) THEN
          WRITE (iolun,fmt='
     +       ('' PXLCL5: ERROR, NJET='',I6,
     +        '' exceeds MXJET'',I6)') njet,mxjet
          go to 995
      END IF
*  Copy jet 4-momenta to output buffer
*  ---- --- - ------- -- ------ ------
      DO 210  ix2 = 1,njet
          DO 200  ix1 = 1,4
              pjet(ix1,ix2) = plund(nlund+ix2,ix1)
 200      CONTINUE
          CALL pxmas4(pjet(1,ix2),pjet(5,ix2))
 210  CONTINUE
      IF (lprt) THEN
          WRITE (iolun,fmt='('' PXLCL5:'')')
          CALL pxprnt(1,njet,5,5,pjet,'E')
          CALL pxpriv('IJMUL',njet,ijmul)
          CALL pxpriv('IPASS',ntrak,ipass)
      END IF

      RETURN
 995  ierr = -1
      RETURN
      END