pxang3.f

Go to the documentation of this file.

CDECK  ID>, PXANG3.
      SUBROUTINE pxang3 (VEC1,VEC2,COST,THET,IERR)
*.*********************************************************
*. ------
*. PXANG3
*. ------
*. SOURCE: VECSUB (V. Blobel)
*. Calculate the angle beteen two 3-vectors
*. Usage     :
*.
*.      INTEGER  IERR
*.      REAL  VEC1 (3.or.more),
*.     +      VEC2 (3.or.more)
*.      REAL  COST,THET
*.
*.      CALL PXANG3 (VEC1,VEC2,COST,THET,IERR)
*.
*. INPUT     : VEC1    The first vector
*. INPUT     : VEC2    The second vector
*. OUTPUT    : COST    Cosine of the angle between the vectors
*. OUTPUT    : THET    The angle between the vectors (radians)
*. OUTPUT    : IERR    = 0 if all is OK ;   = -1 otherwise
*.
*.*********************************************************
      IMPLICIT NONE
      DOUBLE PRECISION ax,bx,cx,dx
      REAL  vec1 (*),vec2 (*)
      REAL  cost,thet
      INTEGER  ix,ierr
      ierr = 0
      ax = 0d0
      bx = 0d0
      cx = 0d0
      DO 120  ix = 1,3
          ax = ax + vec1(ix) * vec1(ix)
          bx = bx + vec2(ix) * vec2(ix)
          cx = cx + vec1(ix) * vec2(ix)
 120  CONTINUE
      dx = dsqrt(ax * bx)
      IF (dx.NE.0.0) THEN
          dx = cx / dx
      ELSE
          WRITE (6,fmt='('' PXANG3: Error, DX='',E12.4)') dx
          ierr = -1
          RETURN
      END IF
      IF (dabs(dx).GT.1.d0) dx = dsign(1.d0,dx)
      cost = dx
      thet = dacos(dx)
      RETURN
      END