cyjet.f

Go to the documentation of this file.

CDECK  ID>, CYJET.
      SUBROUTINE cyjet(NJET,YL,YH,IERR)
*.-----------------------------------------------------------------------
*.
*.    CYJET: Return the largest pair of y-flip values for a required n-jet
*.           configuration.
*.           INPUT:   NJET (integer) Number of jets required
*.           OUTPUT:  YL   (real   ) Lower boundary of y interval
*.                    YH   (real   ) Upper boundary of y interval
*.                    IERR (integer) Error flag, 0=OK.
*.
*.  CREATED :  11-12-1997, STAN BENTVELSEN
*.  LAST MOD:
*.-----------------------------------------------------------------------
      IMPLICIT NONE
      INTEGER nmxy , nmxp
      parameter(nmxy = 300)
      parameter(nmxp = 30)
      DOUBLE PRECISION ytrans(nmxy)
      DOUBLE PRECISION pcmj(nmxp,4,nmxp)
      INTEGER          ntrans(nmxy), njiter, njmax, ntrack
      INTEGER          icmj(nmxp,nmxy)
      COMMON / ckcom / ytrans, pcmj, ntrans, icmj, njiter, njmax, ntrack
      REAL    yl,yh
      INTEGER njet,i,ierr
      INTEGER nprint
      DATA    nprint / 0 /
      SAVE    nprint

      ierr = 0
      yl = -1.
      yh = -1.
      IF(njet.GT.njmax) THEN
         WRITE(*,*) '#################################################'
         WRITE(*,*) '## CYJET: CAMBRIDGE JET FINDER RESOLVED FOR    ##'
         WRITE(*,'(A,I2,A)') ' ##    NUMBER OF JETS BETWEEN 1 AND '
     +        ,njmax,' ONLY     ##'
         WRITE(*,*) '#################################################'
         ierr = 2
         RETURN
      ENDIF
      IF(njet.LT.1) THEN
         WRITE(*,*) 'ERROR IN NJET: ',njet
         ierr = 3
         RETURN
      ENDIF

      DO i=1,njiter
         IF(ntrans(i).EQ.njet) THEN
            yh = 1.*ytrans(i)
            IF(i.LT.njiter) yl = 1.*ytrans(i+1)
            goto 889
         ENDIF
      ENDDO

      IF(nprint.LT.10) THEN
         nprint = nprint + 1
         WRITE(*,*) '#################################################'
         WRITE(*,*) '## CYJET: CAMBRIDGE JET FINDER CANNOT RESOLVE  ##'
         WRITE(*,'(A,I2,A)') ' ##         THIS CONFIGURATION TO A '
     +        ,njet,' JET      ##'
         WRITE(*,*) '#################################################'
      ENDIF

 889  CONTINUE
      RETURN
      END