casso.f

Go to the documentation of this file.

CDECK  ID>, CASSO.
      SUBROUTINE casso(NJET,PNJ,BL,IERR)
*.-----------------------------------------------------------------------
*.
*.    CASSO: Return the jet four-momenta and jet-particle association for a
*.           required number of jets.
*.           (corresponding to largest ycut values)
*.           INPUT:   NJET (integer) Number of jets required
*.           OUTPUT:  PNJ(4,*)(real) Array of jets 4-vectors
*.                    BL(*)(integer) Particle i belongs to jet BL(i)
*.                    IERR (integer) Error flag, 0=OK.
*.
*.  CREATED :  11-12-1997, STAN BENTVELSEN
*.  LAST MOD:
*.-----------------------------------------------------------------------
      IMPLICIT NONE
      INTEGER nmxy , nmxp
      parameter(nmxy = 300)
      parameter(nmxp = 30)
      DOUBLE PRECISION ytrans(nmxy)
      DOUBLE PRECISION pcmj(nmxp,4,nmxp)
      INTEGER          ntrans(nmxy), njiter, njmax, ntrack
      INTEGER          icmj(nmxp,nmxy)
      COMMON / ckcom / ytrans, pcmj, ntrans, icmj, njiter, njmax, ntrack
      INTEGER njet, ierr
      REAL pnj(4,*)
      INTEGER i,j,ii
      INTEGER bl(*)
      INTEGER nprint
      DATA    nprint / 0 /
      SAVE    nprint

      ierr = 0
      IF(njet.GT.njmax.OR.njet.LE.0) THEN
         WRITE(*,*) '#################################################'
         WRITE(*,*) '## CASSO: CAMBRIDGE JET FINDER RESOLVED FOR    ##'
         WRITE(*,'(A,I2,A)') ' ##    NUMBER OF JETS BETWEEN 1 AND '
     +        ,njmax,' ONLY     ##'
         WRITE(*,*) '#################################################'
         DO i=1,njmax
            DO ii=1,4
               pnj(ii,i) = 0
            ENDDO
         ENDDO
         ierr = 2
         RETURN
      ENDIF
      DO i=1,njiter
         IF(ntrans(i).EQ.njet) THEN
            DO j=1,njet
               DO ii=1,4
                  pnj(ii,j) = sngl(pcmj(i,ii,j))
               ENDDO
            ENDDO
            DO j=1,ntrack
               bl(j) = icmj(i,j)
            ENDDO
            goto 889
         ENDIF
      ENDDO

      IF(nprint.LT.10) THEN
         nprint = nprint + 1
         WRITE(*,*) '#################################################'
         WRITE(*,*) '## CASSO: CAMBRIDGE JET FINDER CANNOT RESOLVE  ##'
         WRITE(*,'(A,I2,A)') ' ##         THIS CONFIGURATION TO A '
     +        ,njet,' JET      ##'
         WRITE(*,*) '#################################################'
      ENDIF

 889  CONTINUE
      RETURN
      END