ASSIGN,PRINT="bc2_med.print"
TITLE,S="Medium-Length Single Chicane for LCLS BC2 at 5 GeV"
ASSIGN, ECHO="bc2_med.echo"
!
!------------------------------
!04-OCT-01
!P. Emma
!------------------------------
!
  Cb      : CONSTANT=1.0E10/CLIGHT  ! energy to magnetic rigidity
  rad2deg : CONSTANT=180.0/PI       ! factor to take radians to degrees

  EBC2   := 5.000                   ! BC2 energy (GeV)
  EMITXN := 1.000E-06  ! normalized horizontal emittance (m)
  EMITYN := 1.000E-06  ! normalized vertical emittance (m)
  BLENG  := 0.200E-03  ! bunch length (m)
  ESPRD  := 0.720E-02  ! energy spread (1)
  bX     := 40.0       ! twiss beta x (m)
  aX     := 2.6        ! twiss alpha x
  bY     := 13.0       ! twiss beta y (m)
  aY     := 1.0        ! twiss alpha y

! Input Beta's guess:
! ==================
  TBETX := bX
  TBETY := bY
  TALFX := aX
  TALFY := aY

! set up TWSS0

  TWSS0 : BETA0, ENERGY=EBC2, BETX=TBETX, ALFX=TALFX, BETY=TBETY, ALFY=TALFY

! construct input beam matrix (assumes DY=DPY=0)

  EMITX := EMITXN/(TWSS0[ENERGY]/EMASS)
  EMITY := EMITYN/(TWSS0[ENERGY]/EMASS)
  TGAMX := (1+TWSS0[ALFX]*TWSS0[ALFX])/TWSS0[BETX]
  TGAMY := (1+TWSS0[ALFY]*TWSS0[ALFY])/TWSS0[BETY]
  SIG11 := EMITX*TWSS0[BETX]+TWSS0[DX]*TWSS0[DX]*ESPRD*ESPRD
  SIG21 := -EMITX*TWSS0[ALFX]+TWSS0[DX]*TWSS0[DPX]*ESPRD*ESPRD
  SIG22 := EMITX*TGAMX+TWSS0[DPX]*TWSS0[DPX]*ESPRD*ESPRD
  SIG33 := EMITY*TWSS0[BETY]
  SIG43 := -EMITY*TWSS0[ALFY]
  SIG44 := EMITY*TGAMY
  SIG61 := TWSS0[DX]*ESPRD*ESPRD
  SIG62 := TWSS0[DPX]*ESPRD*ESPRD
  SIG66 := ESPRD*ESPRD
  C21   := SIG21/SQRT(SIG11*SIG22)
  C43   := SIG43/SQRT(SIG33*SIG44)
  C61   := SIG61/SQRT(SIG11*SIG66)
  C62   := SIG62/SQRT(SIG22*SIG66)
  SIG0  : SIGMA0, SIGX=SQRT(SIG11), SIGPX=SQRT(SIG22), R21=C21, &
                  SIGY=SQRT(SIG33), SIGPY=SQRT(SIG44), R43=C43, &
                  SIGT=BLENG      , SIGPT=ESPRD      , R61=C61, R62=C62

  BEAM, PARTICLE=ELECTRON, ENERGY=TWSS0[ENERGY], EX=EMITX, EY=EMITY, &
        SIGT=BLENG, SIGE=ESPRD

  LB   := 0.500                ! BC2-Bend "Z" length [m]
  GB   := 0.025                ! 1D30.5 gap height [m]

! BC2

  Brho := Cb*EBC2             ! beam rigidity at BC2 (kG-m)
  BB   := -16.120960797916    ! chicane bend field (kG)
  RB   := Brho/BB             ! chicane bend radius (m)
  AN   := ASIN(LB/RB)         ! full chicane bend angle (rad)
  LBS  := RB*AN               ! chicane bend path length (m)

! magnet-to-magnet path lengths

  LD   := 5.0                 ! outer bend-to-bend "Z" distance (m)
  LDo  := LD/COS(AN)          ! outer bend-to-bend path length (m)
  LDi  := 1.0                 ! inner bend-to-bend "Z" distance (m)

!bends:
!=====
  B1  : SBEN, L=LBS, ANGLE=+AN, HGAP=GB/2, &
              E1=0,   E2=+AN, FINT=0.5, FINTX=0.5
  B2  : SBEN, L=LBS, ANGLE=-AN, HGAP=GB/2, &
              E1=-AN, E2=0,   FINT=0.5, FINTX=0.5
  B3  : SBEN, L=LBS, ANGLE=-AN, HGAP=GB/2, &
              E1=0,   E2=-AN, FINT=0.5, FINTX=0.5
  B4  : SBEN, L=LBS, ANGLE=+AN, HGAP=GB/2, &
              E1=+AN, E2=0,   FINT=0.5, FINTX=0.5

!drifts:
!======
  Do  : DRIF, L=LDo
  Di  : DRIF, L=LDi
  Df  : DRIF, L=2.0

!beamlines
!=========
  BC2   : LINE=(B1,Do,&
                B2,Di,&
                B3,Do,&
                B4,Df)

    USE,BC2
    MATCH, ENERGY=EBC2
      VARY, BB, STEP=1.E-5
      RMATRIX, #S/#E, RM(5,6)=+0.025,WEIGHT(5,6)=10.
      LMDIF
      MIGRAD
    ENDMATCH
    VALUE, BB
    VALUE, AN*RAD2DEG
    VALUE, AN/SIN(AN)
    VALUE, LDo
!
    USE,BC2
    MATCH, ENERGY=EBC2
      VARY, BB, STEP=1.E-5
      RMATRIX, #S/#E, RM(5,6)=0,WEIGHT(5,6)=0
      TMATRIX, #S/#E, TM(5,6,6)=0,WEIGHT(5,6,6)=0
    ENDMATCH
!
    USE,BC2
    MATCH,ENERGY=EBC2,BETX=bX,BETY=bY,ALFX=aX,ALFY=aY
      VARY,bX,STEP=1.E-5,LOWER=0.01
      VARY,bY,STEP=1.E-5,LOWER=0.01
      VARY,aX,STEP=1.E-5
      VARY,aY,STEP=1.E-5
      CONSTRAINT,B4,BETX=5.00,ALFX=0.0
      CONSTRAINT,#S/#E,BETX<60.,BETY<60.
      LMDIF
      MIGRAD
    ENDMATCH
    VALUE, bX
    VALUE, bY
    VALUE, aX
    VALUE, aY
!
    USE, BC2
    PRINT, FULL
    SELECT, OPTICS, FULL
    TWISS, SAVE, BETA0=TWSS0, TAPE="bc2_med_twiss.tape"
    SURVEY, THETA0=0, X0=0, Z0=0, &
            TAPE="bc2_med_survey.tape"
    ENVELOPE, SAVE, SIGMA0=SIG0, TAPE="bc2_med_envelope.tape"
    PLOT,TABLE=TWISS,HAXIS=S,VAXIS1=BETX,BETY,VAXIS2=DX, &
         VMIN=0.,0.,TITLE="LCLS bc2_med Double-Chicane at 4.54 GeV", &
         STYLE=100,SPLINE=.T.,FILENAME="bc2_med"
!
STOP